Files
proton-drive-linux/packaging/nix/package.nix
T
nvrl 795dd7edb0 feat(gui): offline basemap under the Places map
Places now draws the proton-map-rs basemap that Proton Gallery uses: seas by
depth, lakes, rivers, built-up areas, borders and town names, in light and
dark. Tiles render on two worker threads into the existing tile layer, so
caching, ancestor stand-ins and density restarts work as before. Opening
Places sends no request.

The OpenFreeMap street map stays opt-in and replaces the basemap while it
is turned on. Without the basemap file the map falls back to the coarse
Natural Earth outlines.

scripts/fetch-basemap.sh downloads basemap-v1.pmtiles and checks it against
a pinned SHA-256. The deb, rpm, tarball, local and AUR PKGBUILDs, COPR spec
and Nix package install it to /usr/share/proton-drive-linux. PDFS_BASEMAP
points the app at another copy.

The new credit and preference text is translated in every catalog.
2026-11-22 00:44:14 +01:00

146 lines
4.6 KiB
Nix

# Nix package for the workspace, built from the checkout this file lives in.
# The flake at the repository root exposes it; `nix build` builds it.
{
lib,
rustPlatform,
fetchurl,
adwaita-icon-theme,
pkg-config,
gettext,
glib,
wrapGAppsHook4,
fuse3,
glib-networking,
gtk4,
libadwaita,
webkitgtk_6_0,
libsecret,
dbus,
polkit,
exiftool,
ffmpeg-headless,
withFfmpeg ? true,
}:
let
cargoToml = lib.importTOML ../../Cargo.toml;
# The offline Places basemap, as scripts/fetch-basemap.sh pins it.
basemap = fetchurl {
url = "https://github.com/narrrl/proton-rs/releases/download/basemap-v1/basemap-v1.pmtiles";
sha256 = "ce9acab1b7ed7f15b23e2365b1b6a580db79f4bc4421851ee673eff4c920d280";
};
in
rustPlatform.buildRustPackage {
pname = "proton-drive-linux";
inherit (cargoToml.workspace.package) version;
# Only what the build reads, so editing docs or CI does not rebuild.
src = lib.fileset.toSource {
root = ../..;
fileset = lib.fileset.unions [
../../Cargo.toml
../../Cargo.lock
../../crates
../../po
../../LICENSE
../io.narl.proton-drive-linux.policy
../proton-drive.service
../io.narl.proton-drive-linux.desktop
../io.narl.proton-drive-linux-tray.desktop
../io.narl.proton-drive-linux.svg
../completions.sh
];
};
cargoLock.lockFile = ../../Cargo.lock;
cargoBuildFlags = [
"--bin"
"pdfs"
"--bin"
"pdfs-tray"
"--bin"
"pdfs-app"
"--bin"
"pdfs-prompt"
];
nativeBuildInputs = [
pkg-config
gettext # msgfmt, for po/build.sh
glib # glib-compile-resources, for the GUI's build.rs
wrapGAppsHook4
];
buildInputs = [
fuse3
# TLS for WebKitGTK's GIO: without it the CAPTCHA page fails with "TLS
# support is not available". wrapGAppsHook4 adds it to GIO_EXTRA_MODULES.
glib-networking
# The stock icons the app asks for, such as the Photos and Computers
# sidebar entries. GTK ships only a few itself, and a session without
# Adwaita installed showed the rest as missing. wrapGAppsHook4 adds it to
# XDG_DATA_DIRS.
adwaita-icon-theme
gtk4
libadwaita
webkitgtk_6_0
libsecret
dbus
];
# The app looks for its catalogs here instead of /usr/share/locale.
env.PDFS_LOCALEDIR = "${placeholder "out"}/share/locale";
# The suite mounts FUSE, talks to D-Bus and the kernel keyring, and checks
# permissions a build sandbox does not have; CI runs it on every push.
doCheck = false;
postInstall = ''
install -Dm644 packaging/io.narl.proton-drive-linux.desktop \
$out/share/applications/io.narl.proton-drive-linux.desktop
install -Dm644 packaging/io.narl.proton-drive-linux-tray.desktop \
$out/etc/xdg/autostart/io.narl.proton-drive-linux-tray.desktop
install -Dm644 packaging/io.narl.proton-drive-linux.svg \
$out/share/icons/hicolor/scalable/apps/io.narl.proton-drive-linux.svg
substituteInPlace $out/share/applications/io.narl.proton-drive-linux.desktop \
--replace-fail "Exec=pdfs-app" "Exec=$out/bin/pdfs-app"
substituteInPlace $out/etc/xdg/autostart/io.narl.proton-drive-linux-tray.desktop \
--replace-fail "Exec=pdfs-tray" "Exec=$out/bin/pdfs-tray"
install -Dm644 packaging/io.narl.proton-drive-linux.policy \
$out/share/polkit-1/actions/io.narl.proton-drive-linux.policy
install -Dm644 packaging/proton-drive.service \
$out/lib/systemd/user/proton-drive.service
substituteInPlace $out/lib/systemd/user/proton-drive.service \
--replace-fail "ExecStart=/usr/bin/pdfs" "ExecStart=$out/bin/pdfs"
patchShebangs po/build.sh
po/build.sh $out/share/locale
patchShebangs packaging/completions.sh
packaging/completions.sh $out/bin/pdfs $out/share
# Nix brings new releases, so the app never checks for them itself.
install -Dm644 ${basemap} $out/share/proton-drive-linux/basemap-v1.pmtiles
install -Dm644 /dev/null $out/share/proton-drive-linux/managed-updates
'';
# Thumbnails shell out to exiftool, and to ffmpeg for video. Suffixed, so a
# user's own builds on PATH win. fusermount3 comes from the system: on NixOS
# it is the setuid wrapper in /run/wrappers/bin.
preFixup = ''
gappsWrapperArgs+=(--suffix PATH : ${
lib.makeBinPath ([ exiftool polkit ] ++ lib.optional withFfmpeg ffmpeg-headless)
})
'';
meta = {
description = "Unofficial Proton Drive client for Linux: files-on-demand FUSE mount, CLI, GTK4 app and tray";
homepage = "https://proton-drive.narl.io";
license = lib.licenses.mit;
platforms = lib.platforms.linux;
mainProgram = "pdfs";
};
}